转载

JVM指令分析实例四（数组、switch）

本篇为《JVM指令分析实例》的第四篇，相关实例均使用Oracle JDK 1.8编译，并使用javap生成字节码指令清单。

前几篇传送门：

JVM指令分析实例一（常量、局部变量、for循环）

JVM指令分析实例二（算术运算、常量池、控制结构）

JVM指令分析实例三（方法调用、类实例）

数组

一维原始类型数组

void createBuffer() {
    int buffer[];
    int bufsz = 100;
    int value = 12;
    buffer = new int[bufsz];
    buffer[10] = value;
    value = buffer[11];
}

字节码指令序列

void createBuffer()：
 0: bipush        100   // 将单字节int常量值100压入栈顶
 2: istore_2            // 将栈顶int类型数值100存入第3个局部变量. bufsz = 100
 3: bipush        12    // 将单字节int常量值12压入栈顶
 5: istore_3            // 将栈顶int类型数值12存入第4个局部变量. value = 12
 6: iload_2             // 将第3个int类型局部变量压入栈顶
 7: newarray       int  // 创建int类型数组，并将数组引用值压入栈顶. new int[bufsz]
 9: astore_1            // 将栈顶引用类型值存入第2个局部变量. buffer = new int[bufsz]
10: aload_1             // 将第2个引用类型局部变量压入栈顶
11: bipush        10    // 将单字节int常量10压入栈顶
13: iload_3             // 将第4个int类型局部变量压入栈顶
14: iastore             // 将栈顶int类型数值存入数组的指定索引位置. buffer[10] = value
15: aload_1             // 将第2个引用类型值压入栈顶
16: bipush        11    // 将单字节int常量值11压入栈顶
18: iaload              // 将int类型数组的指定元素压入栈顶
19: istore_3            // 将栈顶int类型数值存入第4个局部变量
20: return

newarray指令

创建一个指定原始类型（如int、float、char等）的数组，并将其引用值压入栈顶。

执行该指令后，将从操作数栈出栈1个参数count，类型为int，表示要创建数组的大小。

iastore指令

从操作数栈读取一个int类型数据并存入指定数组中。

执行该指令后，将从操作数栈出栈3个参数arrayref、index和value，在本例中分别对应于第10、11和13索引位置压入的值。

其中，arrayref是一个引用类型值，指向一个int类型的数组。index和value为int类型，index表示待存入数组位置的索引号，value表示待存入index索引位置的值。

iaload指令

从数组中加载一个int类型数据到操作数栈。

执行该指令后，将从操作数栈出栈2个参数arrayref和index，在本例中分别对应于第15和16索引位置压入的值。

其中，arrayref是一个引用类型值，指向一个int类型的数组。index为int类型，表示待加载数组数据的索引号。

一维引用类型数组

void createThreadArray() {
    Thread threads[];
    int count = 10;
    threads = new Thread[count];
    threads[0] = new Thread();
}

字节码指令序列

void createThreadArray()：
 0: bipush        10    // 将单字节int类型值10压入栈顶
 2: istore_2            // 将栈顶int类型值存入第3个局部变量. count = 10
 3: iload_2             // 将第3个int类型局部变量压入栈顶
 4: anewarray     #15   // class java/lang/Thread. 创建Thread类型数组，并将数组引用值压入栈顶. new Thread[count]
 7: astore_1            // 将栈顶引用类型值存入第2个局部变量
 8: aload_1             // 将第2个引用类型局部变量压入栈顶
 9: iconst_0            // 将int类型常量0压入栈顶
10: new           #15   // class java/lang/Thread. 创建Thread对象，并将引用值压入栈顶
13: dup                 // 复制栈顶值并压入栈顶
14: invokespecial #17   // Method java/lang/Thread."<init>":()V. 调用实例初始化方法
17: aastore             // 将栈顶引用类型值存入数组的指定索引位置. threads[0] = new Thread()
18: return

anewarray指令

创建一个引用类型（如类、接口、数组）数组，并将其引用值压入栈顶。可用于创建一维引用数组，或者用于创建多维数组的一部分。

执行该指令后，将从操作数栈出栈1个参数count，类型为int，表示要创建数组的大小。

aastore指令

（aastore指令与iastore指令作用类似）

从操作数栈读取一个引用类型数据并存入指定数组中。

执行该指令后，将从操作数栈出栈3个参数arrayref、index和value，在本例中分别对应于第8、9和10索引位置压入的值。

其中，arrayref是一个引用类型值，指向一个引用类型的数组。index为int类型，index表示待存入数组位置的索引号。value为引用类型，表示待存入index索引位置的值。

在运行时，value的实际类型必须与arrayref所代表的数组的组件类型相匹配。

多维数组

int[][][] create3DArray() {
    int grid[][][];
    grid = new int[10][5][];
    return grid;
}

字节码指令序列

int[][][] create3DArray()：
0: bipush        10         // 将单字节int类型值10压入栈顶. 第1维
2: iconst_5                 // 将int类型常量5压入栈顶. 第2维
3: multianewarray #16,  2   // class "[[[I". 创建int[][][]类型数组，并将引用值压入栈顶
7: astore_1                 // 将栈顶引用类型值存入第2个局部变量
8: aload_1                  // 将第2个引用类型局部变量压入栈顶
9: areturn                  // 从当前方法返回栈顶引用类型值

multianewarray指令

创建指定类型和指定维度的多维数组（执行该指令时，操作数栈中必须包含各维度的长度值），并将其引用值压入栈顶。可以用于创建所有类型的多维数组。

对于本实例，数组类型为[[[I，即#16对应的常量池中的符号引用。数组维度为2，两个维度的长度值分别为10和5。虽然int[][][]为3维数组，但由于仅指定了前2个维度的长度值，因此指令对应的维度值为2。

如果指定了第3个维度的长度值，那么在iconst_5之后还需要再将1个int类型长度值压入栈。

所有的数组都有一个与之关联的长度属性，可通过arraylength指令访问。

switch语句

编译器会使用tableswitch和lookupswitch指令来生成switch语句的编译代码。

Java虚拟机的tableswitch和lookupswitch指令都只能支持int类型的条件值。

tableswitch指令可以高效地从索引表中确定case语句块的分支偏移量。

当switch语句中的case分支条件值比较稀疏时，tableswitch指令的空间使用率偏低。这种情况下，可以使用lookupswitch指令来代替。

tableswitch指令

int chooseNear(int i) {
    switch(i) {
        case 0: return 0;
        case 1: return 1;
        case 2: return 2;
        default: return -1;
    }
}

字节码指令序列

int chooseNear(int)：
 0: iload_1         // 将第2个int类型局部变量压入栈顶
 1: tableswitch   { // 0 to 2
               0: 28    // 如果case条件值为0，则跳转到索引号为28的指令继续执行
               1: 30    // 如果case条件值为1，则跳转到索引号为30的指令继续执行
               2: 32    // 如果case条件值为2，则跳转到索引号为32的指令继续执行
         default: 34    // 否则，则跳转到索引号为34的指令继续执行
    }
28: iconst_0        // 将int类型常量0压入栈顶
29: ireturn         // 从当前方法返回栈顶int类型数值
30: iconst_1        // 将int类型常量1压入栈顶
31: ireturn         // 从当前方法返回栈顶int类型数值
32: iconst_2        // 将int类型常量2压入栈顶
33: ireturn         // 从当前方法返回栈顶int类型数值
34: iconst_m1       // 将int类型常量-1压入栈顶
35: ireturn         // 从当前方法返回栈顶int类型数值

tableswitch指令

用于switch条件跳转，case值连续（变长指令）。

根据索引值在跳转表中寻找配对的分支并进行跳转。

指令格式：tableswitch padbytes defaultbytes lowbytes highbytes jumptablebytes

padbytes：0~3个填充字节，以使得defaultbytes与方法起始地址（方法内第一条指令的操作码所在的地址）之间的距离是4的位数。
defaultbytes：32位默认跳转地址
lowbytes：32位低值low
highbytes：32位高值high
jumptablebytes：(high-low+1)个32位有符号数值形成的一张零基址跳转表（0-based jump table）

由于采用了索引值定位的方式（可理解为数组随机访问），因此只需要检查索引是否越界，非常高效。

下面结合实例分析一下：

第1条指令的索引号为0，tableswitch指令索引号为1，为了使defaultbytes与方法起始地址之间的距离是4的位数，所以defaultbytes的开始索引号为4。

defaultbytes、lowbytes和highbytes分别占4个字节，总共12个字节。

case高低值分别为2和0，因此jumptablebytes占用(2-0+1)*4=12个字节。

由于defaultbytes的开始索引号为4，defaultbytes~jumptablebytes共占用24个字节，因此紧跟在tableswitch后面的下一条指令的索引号为4+24=28，对应于实例中的指令"28: iconst_0"。

这里顺便提一下，一般情况下，普通的操作数占1个字节，指向常量池的索引值占2个字节（ldc的常量池索引占1个字节，ldc_w、ldc2_w的常量池索引占2个字节）。所以，方法的指令索引号之间有时不是连续的。

lookupswitch指令

int chooseFar(int i) {
    switch(i) {
        case -100: return -1;
        case 0: return 0;
        case 100: return 1;
        default: return -1;
    }
}

字节码指令序列

int chooseFar(int)：
 0: iload_1
 1: lookupswitch  { // 3
          -100: 36
             0: 38
           100: 40
       default: 42
    }
36: iconst_m1
37: ireturn
38: iconst_0
39: ireturn
40: iconst_1
41: ireturn
42: iconst_m1
43: ireturn

lookupswitch指令

用于switch条件跳转，case值不连续（变长指令）。

根据键值（非索引）在跳转表中寻找配对的分支并进行跳转。

指令格式：lookupswitch padbytes defaultbytes npairsbytes matchoffsetbytes